:: Copyright (c) 2019-2023 Digital Energy Cloud Solutions LLC. All Rights Reserved.
:: Authors:
:: Tim Tkachev, <tvtkachev@basistech.ru>
::
:: Licensed under the Apache License, Version 2.0 (the "License");
:: you may not use this file except in compliance with the License.
:: You may obtain a copy of the License at
::
::     http://www.apache.org/licenses/LICENSE-2.0
::
:: Unless required by applicable law or agreed to in writing, software
:: distributed under the License is distributed on an "AS IS" BASIS,
:: WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
:: See the License for the specific language governing permissions and
:: limitations under the License.
::
:: Installer uses basis/decort/decort as path value to provider executable.

@echo off

cd /d "%~dp0"
pushd .\bin\
for %%f in (*.exe) do (
   set filename=%%~nf
)

for /F "tokens=1,2,3,4 delims=_" %%a in ("%filename%") do (
   set version=%%b
   set os=%%c
   set arch=%%d
)

set provider_path=%appdata%\terraform.d\plugins\basistech.ru\tf\dynamix\%version%\%os%_%arch%\

if exist %provider_path% (
    echo Provider directory already exists, checking for decort provider executable..
    copy /y %filename%.exe %provider_path%
        if errorlevel 1 (
            pause 
            exit /b
        )
    call :print_success
    pause
    exit /b
) else (
    echo Creating provider directory..
    mkdir %provider_path%
    if errorlevel 1 (
        pause 
        exit /b
    )
    copy %filename%.exe %provider_path%
    if errorlevel 1 (
        pause 
        exit /b
    )
    call :print_success
    pause
    exit /b
)

:print_success
echo BASIS provider version %version% has been successfully installed
echo:
echo Copy this provider configuration to main.tf file:
echo terraform {
echo   required_providers {
echo     basis = {
echo       version = "%version%"
echo       source  = "basistech.ru/tf/dynamix"
echo     }
echo   }
echo }
goto:eof